buildscript {
    ext {
        def requestedBuildTasks = gradle.startParameter.taskNames.collect { it.toLowerCase() }
        def releaseRequested = requestedBuildTasks.any { it.contains("release") }
        def e2eRequested = requestedBuildTasks.any { it.contains("e2e") }
        def debugRequested = requestedBuildTasks.any { it.contains("debug") }
        def isUniversalNativeBuild = e2eRequested || (debugRequested && !releaseRequested)
        def explicitArchitectures = gradle.startParameter.projectProperties["reactNativeArchitectures"]
        if (isUniversalNativeBuild && explicitArchitectures != null) {
            def requestedArchitectures = explicitArchitectures
                    .split(",")
                    .collect { it.trim() }
                    .findAll { !it.isEmpty() }
            if (requestedArchitectures.size() != 2 ||
                    requestedArchitectures.toSet() != ["arm64-v8a", "x86_64"].toSet()) {
                throw new GradleException(
                        "Debug and e2e builds require exactly arm64-v8a,x86_64 native architectures"
                )
            }
        }
        buildToolsVersion = "36.0.0"
        minSdkVersion = 24
        compileSdkVersion = 36
        targetSdkVersion = 36
        ndkVersion = "27.1.12297006"
        kotlinVersion = "2.1.20"
        reactNativeArchitectures = isUniversalNativeBuild
                ? "arm64-v8a,x86_64"
                : "arm64-v8a"
    }
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath("com.android.tools.build:gradle")
        classpath("com.facebook.react:react-native-gradle-plugin")
        classpath("com.google.gms:google-services:4.5.0")
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin")
    }
}

apply plugin: "com.facebook.react.rootproject"